Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00084_DraggableListMgmt.ls

Text File | 2004-07-11 | 6.7 KB | 255 lines

--
-- DraggableListMgmt
--

property ancestor

-- constants:
property draggableDataMember  -- a created cast member holding pre-runtime gathered and sorted data
property dragSpriteColor  -- the scoreColor of sprites that will be dragged to targets

property draggableList  -- a specially formatted list of draggable sprites
property isDraggableList  -- a list of currently draggable sprites  -- for SinglePoint Draggable activities.


on new me
  -- constants:
  set draggableDataMember = "DraggablePredefines"  -- currently we are using the name of the storage field.
  set dragSpriteColor = 2  -- corresponds to green in the score. (0 = white)

  set ancestor = new (script "TargetListMgmt")

  set isDraggableList = []
  setAt (isDraggableList, numSprites (me), 0)
  gatherDraggableSpriteInfo (me)
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end



-- gather draggable sprite information and return a list:

on gatherDraggableSpriteInfo me
  -- get presaved draggable data if we are in protected mode:
  if the movieName contains ".dxr" or the movieName contains ".exe" then
    set draggableList = value (field draggableDataMember)
    return
  end if

  set initList = [:]
  set num = 0

  -- cycle through all sprites:
  repeat with spr = 1 to numSprites (me)

    -- sprites must be certain colors to be used in the DragDrop Game:
    if the scoreColor of sprite spr = dragSpriteColor then
      set num = num + 1
      -- gather usable information:

      set tmpLst = [#coverNum:the memberNum of sprite spr, #coverLib: the castLibNum of sprite spr, #loc:(the loc of sprite spr), #identifier:value ("#" & the name of member the memberNum of sprite spr of castLib the castLibNum of sprite spr), #myNum:0, #myLib:0, #matchSpriteList:0, #showFlag:0]

      -- add to the initList
      addProp (initList, spr, tmpLst)
    end if
  end repeat

  if not count (initList) then alert "There are no draggable sprites for this activity.  Check sprite score colors."
  else
    set draggableList = initList
    makeField (me, draggableDataMember, draggableList)
  end if
end



-- return TRUE if the sprite is a draggable:

on isDraggable me, spr
  return getAt (isDraggableList, spr)

  -- the following took too long:
  --  set lst = getAProp (draggableList, spr)
  --  if listP (lst) then
  --    if getAProp (lst, #showFlag) then return 1
  --  end if
  --  return 0
end


-- puppet all used sprites to TRUE
-- assign each sprite its personal cover member

on hideDraggables me
  set num = count (draggableList)
  repeat with i = 1 to num
    set spr = getPropAt (draggableList, i)
    hideDraggable (me, spr)
  end repeat
end


on showDraggables me
  set num = count (draggableList)
  repeat with i = 1 to num
    set spr = getPropAt (draggableList, i)
    showDraggable (me, spr)
  end repeat
end


-- hide an answer card by sprite number:

on hideDraggable me, spr
  set lst = getProp (draggableList, spr)
  if voidP (lst) then return 0

  set spr = integer(spr)
  puppetSprite spr, TRUE
  set the memberNum of sprite spr to getProp (lst, #coverNum)
  set the castLibNum of sprite spr to getProp (lst, #coverLib)
  set the loc of sprite spr to getProp (lst, #loc)
  unloadCast (me)
  setAProp (lst, #showFlag, 0)
  setAProp (draggableList, spr, lst)
  setAt (isDraggableList, spr, 0)
  return 1
end


-- show a draggable by sprite number.
-- return TRUE if a successful card turning.

on showDraggable me, spr
  set lst = getAProp (draggableList, spr)
  if voidP (lst) then return 0

  set the memberNum of sprite spr to getProp (lst, #myNum)
  set the castLibNum of sprite spr to getProp (lst, #myLib)
  set the loc of sprite spr to getProp (lst, #loc)
  unloadCast (me)
  setAProp (lst, #showFlag, 1)
  setAProp (draggableList, spr, lst)
  setAt (isDraggableList, spr, 1)
  return 1
end


-- stick an answer card where it is by sprite number:

on stickDraggable me, spr
  set lst = getProp (draggableList, spr)
  if voidP (lst) then return 0

  set spr = integer(spr)
  puppetSprite spr, TRUE

  setAProp (lst, #showFlag, 0)
  setAProp (draggableList, spr, lst)

  setAt (isDraggableList, spr, 0)  -- new feature for #SinglePointStick  -- try other stick types
  return 1
end



-- check a draggable against it's matchSpriteList to see if it intersects one of its targets.
-- by sprite number.
-- return zero or the matching sprite number.
-- this method does not mark the draggable (or the target) as shown.
-- it just checks for a match.
-- spr is the sprite of the draggable, testSpr is the sprite of the one pixel pointer under the mouse.


on checkMatch me, spr, pointerSpr
  set lst = getAProp (draggableList, spr)
  set matchList = getAProp (lst, #matchSpriteList)

  if voidP (pointerSpr) then
    set mRect = rect (the mouseH, the mouseV, the mouseH + 16, the mouseV + 16)
    repeat with matchSprite in matchList
      set tmp = intersect(mRect, the rect of sprite matchSprite)
      if tmp <> rect (0,0,0,0) then return matchSprite

      -- alternative (not as fine a match):
      -- if inside (endLoc, the rect of sprite matchSprite) then return matchSprite
      -- if end drag point intersects matchSprite then return matchSprite

    end repeat
    return 0
  end if

  -- check by the one pixel pointer sprite under the cursor:

  repeat with matchSprite in matchList

    --    set tmp = intersect(mRect, the rect of sprite matchSprite)
    --    if tmp <> rect (0,0,0,0) then return matchSprite

    if sprite pointerSpr intersects matchSprite then return matchSprite
  end repeat

  return 0
end


-- check to see if we are done by checking to see if all draggables have been dropped correctly:

on checkDone me
  set num = count (draggableList)
  repeat with i = 1 to num
    set spr = getPropAt (draggableList, i)
    set lst = getProp (draggableList, spr)
    -- if a sprite remains showing on the screen then we are not done.
    -- #showFlag is used here for data structure compatibility with Match Game.
    -- (the name may be altered later)
    if getAProp (lst, #showFlag) then return 0
  end repeat
  return 1
end


-- return a list of currently draggable screen elements:

on getDraggableList me
  set lst = []
  repeat with i = 1 to numSprites (me)
    if isDraggable (me, i) then add (lst, i)
  end repeat
  return lst
end


-- return a random draggable sprite:

on getRandomDraggable me
  set lst = getDraggableList (me)
  if count (lst) then
    set num = random (count (lst))
    set spr = getAt (lst, num)
    return spr
  else
    return 0
  end if
end



on getNextDraggable me
  repeat with spr = 1 to numSprites (me)
    if isDraggable (me, spr) then return spr
  end repeat
  return 0
end

on getID me, spr
  set lst = getAProp (draggableList, spr)
  return getAProp (lst, #identifier)
end